Индикаторы Аллигатор
Gary Randall
По книге Bill William "Trading Chaos"
Chaos Blue BL
Синяя линия баланса - челюсти
13-периодная средняя, сдвинутая на 8 периодов
Ref(Wilders(MP(),13),-8);
Chaos Red BL
Красная линия баланса - зубы
8-периодная средняя, сдвинутая на 5 периодов
Ref(Wilders(MP(),8),-5);
Chaos Green BL
Зеленая линия баланса - губы
5-периодная средняя, сдвинутая на 3 периода
Ref(Wilders(MP(),5),-3);
Chaos Gator
Аллигатор хаоса
Рисуется в виде гистограммы
green := Fml("Chaos Green BL");
red := Fml("Chaos Red BL");
blue := Fml("Chaos Blue BL");
If(green > red AND red > blue, green - blue,
If(blue > red AND red > green, green - blue, 0));
Chaos AO
Chaos Awsome Oscillator - измеряет моментум
Очень похож на MFI
Рисуется в виде гистограммы
Mov(MP(),5,S) - Mov(MP(),34,S);
Chaos AO Signal Line
Сигнальная линия для Chaos Awsome Oscillator
Накладывается в виде линни поверх гистограммы AO
Mov(Mov(MP(),5,S) - Mov(MP(),34,S),5,S)
Chaos AC
Chaos Accelerator/Decelerator Oscillator
Измеряет ускорение
Рисуется в виде гистограммы
Fml("Chaos AO") - Mov(Fml("Chaos AO"),5,S);
Chaos Fractal
Фракталы (простая версия +1=Вверх, -1=Вниз)
High1 := Ref(HIGH,-2);
High2 := Ref(HIGH,-1);
High3 := Ref(HIGH,0);
High4 := Ref(HIGH,1);
High5 := Ref(HIGH,2);
Low1 := Ref(LOW,-2);
Low2 := Ref(LOW,-1);
Low3 := Ref(LOW,0);
Low4:= Ref(LOW,1);
Low5:= Ref(LOW,2);
Fractal:= If((High3 > High1) AND (High3 > High2) AND (High3 > High4) AND
(High3 > High5), +1,0);
Fractal :=
If((Low3 < Low1) AND (Low3 < Low2) AND
(Low3 < Low4) AND (Low3 < Low5),
If(Fractal > 0, 0, -1), Fractal);
Fractal;
